Obsah
Včera na maratóne 30 funkcií Excelu za 30 dní našli sme prvky poľa pomocou funkcie MATCH (VYHĽADÁVANIE) a zistil, že to funguje skvele v tíme s ďalšími funkciami ako napr VLOOKUP (VLOOKUP) a INDEX (INDEX).
20. deň nášho maratónu sa budeme venovať štúdiu funkcie ADRESA (ADRESA). Vráti adresu bunky v textovom formáte pomocou čísla riadka a stĺpca. Potrebujeme túto adresu? Dá sa to isté urobiť s inými funkciami?
Poďme sa pozrieť na detaily funkcie ADRESA (ADRESA) a naštudujte si príklady práce s ňou. Ak máte ďalšie informácie alebo príklady, podeľte sa o ne v komentároch.
Funkcia 20: ADRESA
Funkcie ADRESA (ADDRESS) vráti odkaz na bunku ako text na základe čísla riadka a stĺpca. Môže vrátiť absolútnu alebo relatívnu adresu v štýle odkazu. A1 or R1C1. Okrem toho môže byť vo výsledku zahrnutý aj názov listu.
Ako sa dá použiť funkcia ADRESA?
Funkcie ADRESA (ADDRESS) môže vrátiť adresu bunky alebo pracovať v spojení s inými funkciami, aby:
- Získajte adresu bunky s číslom riadka a stĺpca.
- Nájdite hodnotu bunky tak, že poznáte číslo riadku a stĺpca.
- Vráti adresu bunky s najväčšou hodnotou.
Syntax ADDRESS (ADDRESS)
Funkcie ADRESA (ADDRESS) má nasledujúcu syntax:
ADDRESS(row_num,column_num,[abs_num],[a1],[sheet_text])
АДРЕС(номер_строки;номер_столбца;[тип_ссылки];[а1];[имя_листа])
- abs_num (typ_odkazu) – ak sa rovná 1 alebo nie je zadaný vôbec, funkcia vráti absolútnu adresu ($A$1). Ak chcete získať relatívnu adresu (A1), použite hodnotu 4. Ďalšie možnosti: 2=A$1, 3=$A1.
- a1 – ak je TRUE (TRUE) alebo nie je zadané vôbec, funkcia vráti odkaz v štýle A1, ak FALSE (FALSE), tak v štýle R1C1.
- arch_text (názov_hárka) – názov hárka je možné zadať, ak ho chcete vidieť vo výsledku vrátenom funkciou.
Pasce ADRESA
Funkcie ADRESA (ADDRESS) vráti iba adresu bunky ako textový reťazec. Ak potrebujete hodnotu bunky, použite ju ako argument funkcie NEPRIAME (NEPRIAME) alebo použite jeden z alternatívnych vzorcov uvedených v príklade 2.
Príklad 1: Získajte adresu bunky podľa čísla riadku a stĺpca
Používanie funkcií ADRESA (ADRESA) Adresu bunky môžete získať ako text pomocou čísla riadka a stĺpca. Ak zadáte iba tieto dva argumenty, výsledkom bude absolútna adresa napísaná v štýle odkazu A1.
=ADDRESS($C$2,$C$3)
=АДРЕС($C$2;$C$3)
Absolútne alebo relatívne
Ak nezadáte hodnotu argumentu abs_num (typ_odkazu) vo vzorci, výsledkom je absolútna referencia.
Ak chcete vidieť adresu ako relatívny odkaz, môžete ju nahradiť ako argument abs_num (referenčný_typ). 4.
=ADDRESS($C$2,$C$3,4)
=АДРЕС($C$2;$C$3;4)
A1 alebo R1C1
Na štýl odkazov R1C1, namiesto predvoleného štýlu A1, Pre argument musíte zadať FALSE a1.
=ADDRESS($C$2,$C$3,1,FALSE)
=АДРЕС($C$2;$C$3;1;ЛОЖЬ)
Názov listu
Posledným argumentom je názov listu. Ak potrebujete tento názov vo výsledku, zadajte ho ako argument list_text (názov_hárka).
=ADDRESS($C$2,$C$3,1,TRUE,"Ex02")
=АДРЕС($C$2;$C$3;1;ИСТИНА;"Ex02")
Príklad 2: Nájdite hodnotu bunky pomocou čísla riadku a stĺpca
Funkcie ADRESA (ADDRESS) vráti adresu bunky ako text, nie ako platný odkaz. Ak potrebujete získať hodnotu bunky, môžete použiť výsledok vrátený funkciou ADRESA (ADDRESS), ako argument pre NEPRIAME (NEPRIAME). Budeme študovať funkciu NEPRIAME (NEPRIAME) neskôr v maratóne 30 funkcií Excelu za 30 dní.
=INDIRECT(ADDRESS(C2,C3))
=ДВССЫЛ(АДРЕС(C2;C3))
Funkcie NEPRIAME (NEPRIAME) môže fungovať bez tejto funkcie ADRESA (ADRESA). Tu je návod, ako môžete pomocou operátora zreťazenia “&“, zaslepte požadovanú adresu v štýle R1C1 a v dôsledku toho získajte hodnotu bunky:
=INDIRECT("R"&C2&"C"&C3,FALSE)
=ДВССЫЛ("R"&C2&"C"&C3;ЛОЖЬ)
Funkcie INDEX (INDEX) môže tiež vrátiť hodnotu bunky, ak je zadané číslo riadka a stĺpca:
=INDEX(1:5000,C2,C3)
=ИНДЕКС(1:5000;C2;C3)
1:5000 je prvých 5000 XNUMX riadkov hárka programu Excel.
Príklad 3: Vráťte adresu bunky s maximálnou hodnotou
V tomto príklade nájdeme bunku s maximálnou hodnotou a použijeme funkciu ADRESA (ADDRESS), aby ste získali jej adresu.
Funkcie MAX (MAX) nájde maximálny počet v stĺpci C.
=MAX(C3:C8)
=МАКС(C3:C8)
Nasleduje funkcia ADRESA (ADRESA) v kombinácii s MATCH (MATCH), ktorý nájde číslo riadku a STĹPIK (COLUMN), ktorý určuje číslo stĺpca.
=ADDRESS(MATCH(F3,C:C,0),COLUMN(C2))
=АДРЕС(ПОИСКПОЗ(F3;C:C;0);СТОЛБЕЦ(C2))